InstallOptions 2

關於在 Modern UI 裡使用 InstallOptions 的更多訊息請觀看 Modern UI 文件。

首先，你需要在 .onInit 函數里把對話的 INI 檔案釋放出來。

Function .onInit

  InitPluginsDir
  File /oname=$PLUGINSDIR\test.ini test.ini

FunctionEnd

你可以在 page 函數里調用 InstallOptions，關於頁面系統的更多訊息請觀看 NSIS 文件。例如:

Page custom SetCustom ValidateCustom

InstallOptions DLL 有三個函數:

• dialog - 立即建立對話
• initDialog - 先在記憶體裡建立，但未顯示出來
• show - 把在記憶體裡建立的對話顯示出來

通常，你只需要 dialog 函數就可以了:

Function SetCustom ;FunctionName defined with Page command

  ;Display the Install Options dialog

  Push $R0

  InstallOptions::dialog $PLUGINSDIR\test.ini
  Pop $R0

FunctionEnd

要取得用戶的輸入，可以用 ReadINIStr 來讀取某個 Field 的 State 值:

ReadINIStr $R0 "$PLUGINSDIR\test.ini" "Field 1" "State"

注意:

一些 InstallOptions 的值已被轉義(類似於 C 字串)來使得一些特定字元可以在 INI 檔案裡使用。受影響的值為:

• ValidateText 字段
• Label 字段的 Text 值
• 帶有 MULTILINE 標記的 Text 字段的 State 值

轉義的字元如下:

下面的函數可以用來轉換這些字元:

; 轉換 NSIS 字串到 InstallOptions 字串
; 使用:
;   Push <NSIS-字串>
;   Call Nsis2Io
;   Pop <IO-字串>
Function Nsis2Io
  Exch $0 ; The source
  Push $1 ; The output
  Push $2 ; Temporary char
  StrCpy $1 "" ; Initialise the output
loop:
  StrCpy $2 $0 1 ; Get the next source char
  StrCmp $2 "" done ; Abort when none left
    StrCpy $0 $0 "" 1 ; Remove it from the source
    StrCmp $2 "\" "" +3 ; Back-slash?
      StrCpy $1 "$1\\"
      Goto loop
    StrCmp $2 "$\r" "" +3 ; Carriage return?
      StrCpy $1 "$1\r"
      Goto loop
    StrCmp $2 "$\n" "" +3 ; Line feed?
      StrCpy $1 "$1\n"
      Goto loop
    StrCmp $2 "$\t" "" +3 ; Tab?
      StrCpy $1 "$1\t"
      Goto loop
    StrCpy $1 "$1$2" ; Anything else
    Goto loop
done:
  StrCpy $0 $1
  Pop $2
  Pop $1
  Exch $0
FunctionEnd

; 轉換 InstallOptions 字串到 NSIS 字串
; Usage:
;   Push <IO-字串>
;   Call Io2Nsis
;   Pop <NSIS-字串>
Function Io2Nsis
  Exch $0 ; The source
  Push $1 ; The output
  Push $2 ; Temporary char
  StrCpy $1 "" ; Initialise the output
loop:
  StrCpy $2 $0 1 ; Get the next source char
  StrCmp $2 "" done ; Abort when none left
    StrCpy $0 $0 "" 1 ; Remove it from the source
    StrCmp $2 "\" +3 ; Escape character?
      StrCpy $1 "$1$2" ; If not just output
      Goto loop
    StrCpy $2 $0 1 ; Get the next source char
    StrCpy $0 $0 "" 1 ; Remove it from the source
    StrCmp $2 "\" "" +3 ; Back-slash?
      StrCpy $1 "$1\"
      Goto loop
    StrCmp $2 "r" "" +3 ; Carriage return?
      StrCpy $1 "$1$\r"
      Goto loop
    StrCmp $2 "n" "" +3 ; Line feed?
      StrCpy $1 "$1$\n"
      Goto loop
    StrCmp $2 "t" "" +3 ; Tab?
      StrCpy $1 "$1$\t"
      Goto loop
    StrCpy $1 "$1$2" ; Anything else (should never get here)
    Goto loop
done:
  StrCpy $0 $1
  Pop $2
  Pop $1
  Exch $0
FunctionEnd

如果你想驗證頁面的輸入，例如，你需要知道用戶是否填寫了文字框，當驗證失敗時可以使用頁面的 leave 函數並調用 Abort 來阻止用戶繼續:

Function ValidateCustom

  ReadINIStr $R0 "$PLUGINSDIR\test.ini" "Field 1" "State"
  StrCmp $R0 "" 0 +3
    MessageBox MB_ICONEXCLAMATION|MB_OK "請輸入一個名稱。"
    Abort

FunctionEnd

在你調用 InstallOptions 之後，InstallOptions 會新增一個字串到堆棧，新增的字串可能是下列之一:

• success - 用戶按了下一步按鈕
• back - 用戶按了上一步按鈕
• cancel - 用戶按了取消按鈕
• error - 發生了一個錯誤，對話無法顯示

通常，你不需要檢測這些值，但是你應該把它們從堆棧移除 (看上面的例子)。

僅當你需要的時候才回去檢測返回值，比如檢測用戶按了什麼按鈕。